メインコンテンツへスキップ

【Terraform学習 #02】VPCからEC2まで作ってネットワークの基本を理解する

    【Terraform学習 #02 】VPCからEC2まで作ってネットワークの基本を理解する

    前回は、Terraformの基本操作を学ぶために、既存のDefault VPC / Default Subnetを利用してEC2を1台作成しました。

    今回は一歩進めて、EC2を置くネットワーク自体をTerraformで作成します。

    今回作るのは、以下のシンプルな構成です。

    AWS
    └── VPC 10.10.0.0/16
        ├── Internet Gateway
        │
        └── Public Subnet 10.10.1.0/24
             │
             ├── Route Table
             │    ├── 10.10.0.0/16 → local
             │    └── 0.0.0.0/0   → Internet Gateway
             │
             └── EC2 × 1
                  └── Public IPv4なし

    今回の目的は、単にリソースを作ることではなく、

    • VPCとSubnetの関係

    • Internet Gatewayの役割

    • Route Tableの役割

    • Public Subnetとは何か

    • TerraformでResource同士をどう関連付けるのか

    を理解することです。

    EC2へのSSH接続やWeb公開は行いません。


    ① Input

    VPCとは

    VPC(Virtual Private Cloud)は、AWS上に作成する論理的に分離された仮想ネットワークです。

    今回は、

    10.10.0.0/16

    をVPCのCIDRとして利用します。

    このVPCの中に、さらに小さいネットワークとしてSubnetを作成します。

    VPC 10.10.0.0/16
    └── Subnet 10.10.1.0/24

    Terraformでは `aws_vpc` Resourceを使用します。

    resource "aws_vpc" "lab" {
      cidr_block = "10.10.0.0/16"
    }

    Subnetとは

    Subnetは、VPCのIPアドレス範囲を分割したネットワークです。

    今回は、

    10.10.1.0/24

    を利用します。

    Terraformでは、

    resource "aws_subnet" "public" {
      vpc_id     = aws_vpc.lab.id
      cidr_block = "10.10.1.0/24"
    }

    と記述します。

    ここで重要なのが、

    vpc_id = aws_vpc.lab.id

    です。

    `aws_vpc.lab.id` は変数ではなく、Terraformで作成した `aws_vpc.lab` の実際のVPC IDを参照しています。

    つまり、

    aws_vpc.lab
        ↓
    AWSでVPC作成
        ↓
    実際のVPC ID
        ↓
    aws_subnet.public の vpc_id に利用

    という流れです。

    `vpc-xxxxx` のような実際のIDを自分で確認してコードへ書く必要はありません。


    Internet Gatewayとは

    Internet Gateway(IGW)は、VPCとインターネットの間の通信に利用するVPCコンポーネントです。

    Terraformでは、

    resource "aws_internet_gateway" "lab" {
      vpc_id = aws_vpc.lab.id
    }

    と記述します。

    ただし、VPCにInternet GatewayをAttachしただけでは、SubnetがPublic Subnetになるわけではありません。

    Internet Gatewayへ通信を送るためのRouteが必要です。


    Route Tableとは

    Route Tableは、

    この宛先への通信を、どこへ送るか

    を決めるルールです。

    今回のRoute Tableは、

    Destination     Target
    10.10.0.0/16 → local
    0.0.0.0/0    → Internet Gateway

    という形になります。

    `10.10.0.0/16 → local` は、VPC内部の通信に利用するRouteです。

    一方、

    0.0.0.0/0 → Internet Gateway

    は、VPC内部向けなどのより具体的なRouteに該当しないIPv4通信をInternet Gatewayへ送るRouteです。

    今回はPublic Subnet用にCustom Route Tableを作成し、Subnetへ明示的に関連付けます。


    Public Subnetとは

    今回特に理解したかったポイントです。

    AWSでは、Internet GatewayへのRouteを持つRoute Tableに関連付けられたSubnetをPublic Subnetと呼びます。

    つまり、

    Public Subnet
    =
    EC2にPublic IPが付いているSubnet

    ではありません。

    今回のSubnetは、

    0.0.0.0/0 → Internet Gateway

    を持つのでPublic Subnetです。

    しかし、EC2には、

    associate_public_ip_address = false

    を指定しています。

    そのため、

    Subnet
    → Public Subnet
    
    EC2
    → Public IPv4なし

    という構成になります。

    Public Subnetであっても、EC2自身にPublic IPv4がなければ、このEC2がInternet Gateway経由で直接IPv4インターネット通信できる構成にはなりません。

    「SubnetがPublicか」と「EC2がPublic IPv4を持つか」は別に考える必要があります。


    ② Terraform作成

    今回は学習内容を追いやすくするため、前回と同じく `main.tf` 1ファイルで進めます。

    terraform-aws-02/
    └── main.tf

    main.tf

    terraform {
      required_version = ">= 1.15.0"
    
      required_providers {
        aws = {
          source  = "hashicorp/aws"
          version = "~> 6.0"
        }
      }
    }
    
    provider "aws" {
      region = "ap-northeast-1"
    }
    
    
    # Amazon Linux 2023の最新AMIを取得
    data "aws_ssm_parameter" "amazon_linux_2023" {
      name = "/aws/service/ami-amazon-linux-latest/al2023-ami-kernel-default-x86_64"
    }
    
    # 利用可能なAvailability Zoneを取得
    data "aws_availability_zones" "available" {
      state = "available"
    }
    
    
    # VPC
    resource "aws_vpc" "lab" {
      cidr_block = "10.10.0.0/16"
    
      enable_dns_support   = true
      enable_dns_hostnames = true
    
      tags = {
        Name = "terraform-lab-02-vpc"
      }
    }
    
    
    # Public Subnet
    resource "aws_subnet" "public" {
      vpc_id            = aws_vpc.lab.id
      cidr_block        = "10.10.1.0/24"
      availability_zone = data.aws_availability_zones.available.names[0]
    
      map_public_ip_on_launch = false
    
      tags = {
        Name = "terraform-lab-02-public-subnet"
      }
    }
    
    
    # Internet Gateway
    resource "aws_internet_gateway" "lab" {
      vpc_id = aws_vpc.lab.id
    
      tags = {
        Name = "terraform-lab-02-igw"
      }
    }
    
    
    # Route Table
    resource "aws_route_table" "public" {
      vpc_id = aws_vpc.lab.id
    
      route {
        cidr_block = "0.0.0.0/0"
        gateway_id = aws_internet_gateway.lab.id
      }
    
      tags = {
        Name = "terraform-lab-02-public-rt"
      }
    }
    
    
    # Route TableとSubnetを関連付け
    resource "aws_route_table_association" "public" {
      subnet_id      = aws_subnet.public.id
      route_table_id = aws_route_table.public.id
    }
    
    
    # EC2
    resource "aws_instance" "terraform_lab" {
      ami           = data.aws_ssm_parameter.amazon_linux_2023.value
      instance_type = "t3.micro"
    
      subnet_id = aws_subnet.public.id
    
      associate_public_ip_address = false
    
      metadata_options {
        http_tokens = "required"
      }
    
      root_block_device {
        encrypted = true
      }
    
      tags = {
        Name = "terraform-lab-02-ec2"
      }
    }

    今回はSecurity Groupを明示的に作成していません。

    そのため、EC2では今回作成したVPCのDefault Security Groupが利用されます。

    SSH接続やWeb公開は行わず、Security Group自体は今後別の回でTerraform管理していきます。


    ③ 実践

    terraform init

    まず作業ディレクトリを初期化します。

    terraform init

    Terraform Providerなど、必要なものを利用できる状態にします。


    terraform fmt

    terraform fmt

    今回は `main.tf` が整形対象になりました。


    terraform validate

    terraform validate

    Terraformの設定ファイルが、構文やProviderのスキーマ上で妥当か確認します。

    今回は最終的に、

    Success! The configuration is valid.

    となりました。

    途中でResource参照を、

    route_table.public.id

    と書いてしまい、Terraformから「そのResourceは宣言されていない」というエラーが出ました。

    正しくは、

    aws_route_table.public.id

    です。

    TerraformのResource参照は基本的に、

    <Resource Type>.<Resource Name>.<Attribute>

    という形になることを改めて確認できました。


    AWS認証

    TerraformのAWS ProviderがAWSを操作するには、AWS認証情報が必要です。

    途中で、

    Error: No valid credential sources found

    というエラーも発生しました。

    TerraformコードへAccess KeyやSecret Access Keyを直接書くのではなく、AWS CLI側で認証し、その認証情報をTerraformから利用する形にしています。

    認証情報そのものはコードや記事には掲載しません。


    terraform plan

    次に、

    terraform plan

    で変更内容を確認します。

    今回作成するManaged Resourceは以下です。

    aws_vpc.lab
    aws_subnet.public
    aws_internet_gateway.lab
    aws_route_table.public
    aws_route_table_association.public
    aws_instance.terraform_lab

    また、

    data.aws_ssm_parameter.amazon_linux_2023
    data.aws_availability_zones.available

    はResourceを新しく作るのではなく、AWS上の既存情報を取得するData Sourceです。


    terraform apply

    Planを確認したあと、

    terraform apply

    を実行しました。

    結果は、

    Apply complete! Resources: 6 added, 0 changed, 0 destroyed.

    でした。

    VPC、Subnet、Internet Gateway、Route Table、Route Table Association、EC2の6つがTerraformのManaged Resourceとして作成されました。


    ④ 今回理解したポイント

    Resource同士の参照で実IDを書かなくてよい

    今回何度も登場したのが、

    aws_vpc.lab.id
    aws_subnet.public.id
    aws_internet_gateway.lab.id
    aws_route_table.public.id

    のような書き方です。

    例えば、

    vpc_id = aws_vpc.lab.id

    なら、

    `aws_vpc.lab` で作ったVPCのIDを使う

    という意味です。

    AWSコンソールからVPC IDをコピーして、

    vpc_id = "vpc-xxxxx"

    のようにベタ書きする必要がありません。

    さらに、この参照関係によってTerraformはResource同士の依存関係も判断します。

    例えばSubnetはVPC IDを必要とするので、VPCより先にSubnetを作ることはできません。

    手順書のように「VPCを作る → IDを確認する → Subnetを作る」と順番を細かく指定するのではなく、Resource同士の関係をコードで定義できるのがTerraformらしい部分だと感じました。


    VPC内部のlocal Route

    VPCのRoute Tableには、VPC内部通信のための `local` Routeがあります。

    今回なら、

    10.10.0.0/16 → local

    です。

    このRouteによって、VPC CIDR内のSubnet間通信をVPC内部でルーティングできます。

    最初はL2スイッチのようなイメージを持っていましたが、考え方としては「VPC内のIPネットワーク間をつなぐL3のRoute」と捉える方が分かりやすそうです。


    Route Tableを作らないSubnetも存在できる

    Subnetは必ず何らかのRoute Tableと関連付いています。

    Custom Route Tableを明示的に関連付けなければ、VPCのMain Route Tableを利用します。

    今回は、

    0.0.0.0/0 → Internet Gateway

    というPublic Subnet用の経路を明示的に持たせたかったため、Custom Route Tableを作成してSubnetへ関連付けています。


    Public SubnetとPublic IPは別

    今回一番整理できたのはここでした。

    Public Subnet
    → Route TableにInternet GatewayへのRouteがある
    
    Public IPv4
    → EC2のPrivate IPv4に対してAWS側で紐付けられる外向けのIPv4アドレス

    つまり、Public SubnetにEC2を置いただけでは、EC2にPublic IPv4が必ず付くわけではありません。

    今回のEC2は、

    associate_public_ip_address = false

    なのでPublic IPv4を持ちません。

    ネットワークの経路と、EC2自身がどのIPアドレスを持つかは分けて考える必要があります。


    Terraformは「リソースの関係」を書く

    第1回はEC2を1台作るだけだったので、Terraformの基本操作を理解することが中心でした。

    今回は、

    VPC
    ↓
    Subnet
    
    VPC
    ↓
    Internet Gateway
    
    VPC
    ↓
    Route Table
    ↓
    Subnet
    
    Subnet
    ↓
    EC2

    と、Resource同士をつなげるコードが増えました。

    このあたりから、Terraformが単にAWS APIを実行するだけではなく、

    どのResourceが、どのResourceに依存しているか

    をコードとして表現するツールだという感覚が少し分かってきました。


    ⑤ terraform destroy

    検証後は、

    terraform destroy

    を実行しました。

    結果は、

    Destroy complete! Resources: 6 destroyed.

    でした。

    今回Terraformで作成したManaged Resourceを削除して、検証を終了しました。


    まとめ

    今回はTerraformで、

    VPC
    ├── Internet Gateway
    └── Public Subnet
         ├── Route Table
         └── EC2

    というネットワークを含む構成を作成しました。

    今回理解できたことは、

    • VPCの中にSubnetを作る

    • Resource同士は実際のIDをベタ書きせず参照できる

    • Internet GatewayだけではPublic Subnetにならない

    • Route Tableの `0.0.0.0/0 → IGW` がPublic Subnetを作る重要な要素

    • Public SubnetとEC2のPublic IPv4は別の概念

    • VPC内部には `local` Routeがある

    • TerraformはResource間の参照から依存関係を判断する

    という点です。

    第1回では「Terraformを使えばAWSリソースを作れる」というところまででしたが、第2回ではネットワークを含めて複数のResourceをつなげることで、少しTerraformらしい構成になってきました。

    次回は、Security Groupなどを追加して、EC2の通信制御までTerraformで管理する構成へ広げていきたいと思います。


    参考資料

    HashiCorp AWS Provider - VPC
    https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/vpc

    HashiCorp AWS Provider - Subnet
    https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/subnet

    HashiCorp AWS Provider - Internet Gateway
    https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/internet_gateway

    HashiCorp AWS Provider - Route Table
    https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/route_table

    HashiCorp AWS Provider - Route Table Association
    https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/route_table_association

    AWS - Internet Gateway
    https://docs.aws.amazon.com/vpc/latest/userguide/VPC_Internet_Gateway.html

    AWS - Subnet Route Tables
    https://docs.aws.amazon.com/vpc/latest/userguide/subnet-route-tables.html

    HashiCorp - Terraform Dependency Graph
    https://developer.hashicorp.com/terraform/internals/graph


    ※ 本記事は個人の学習・検証内容をまとめたものです。
    実際の業務・本番環境では、要件に応じてSecurity Group、IAM、冗長化、監視、ログ、State管理、ネットワーク設計などを別途検討する必要があります。

    あなたへのおすすめ